How To use the SPI and LCD driver

Configuration of SPI

The LCD can receive serial data via SPI interface, but this has to be first configured :
see How To configure the SPI and the LCD driver KS 0074.
Then you must :

Initialise the LCD screen
Send the data, periodically if you want to display variables changes or so...

LCD driver initialisation sequence

We must clear the LCD screen and configure correctly :

;----------------------------------------------------------------

; initialisation de l'écran LCD

;----------------------------------------------------------------

;   SPI_Config 2  ; SPI pour LCD  config identique

      LDP  #LCDlo

      SPLK  #000h, LCDlo

      SPLK  #0C0h, LCDhi

      DispLCD 1          ;  foncé

      ; observers

      LDP     #00E1h

      LACC    PADATDIR

      OR      #1                  ; A0= +5V

      SACL    PADATDIR

      Attends 2000

      LDP  #LCDlo

      SPLK  #080h, LCDlo

      SPLK  #000h, LCDhi

      DispLCD 1         ; clear LCD, 1.53 ms

      Attends 2000

        ; observers

      LDP     #00E1h

      LACC    PADATDIR

      AND     #0FFFEh             ; A0= 0V

      SACL    PADATDIR

;   LDP    #LCDlo

;   SPLK #050h, LCDlo    ; display off, cursor On

;   SPLK #000h, LCDhi

;   DispLCD 1

;   Attends  2000

      LDP  #LCDlo

      SPLK  #060h, LCDlo        ; increment, 1.53 ms

      SPLK  #000h, LCDhi

      DispLCD 1

      Attends 2000

      LDP  #LCDlo

      SPLK  #030h, LCDlo        ; display on, cursor Off

      SPLK  #000h, LCDhi

      DispLCD 1

      Attends 2000

;   LDP    #LCDlo

;   SPLK #080h, LCDlo

;   SPLK #020h, LCDhi

;   DispLCD 2            ; Char "A"

;   Attends  500

;   LDP    #LCDlo

;   SPLK #040h, LCDlo

;   SPLK #020h, LCDhi

;   DispLCD 2            ; Char "B"

;   Attends  500

      LDP #LCDupdate

      SPLK  #1, LCDupdate  ; doit MAJ la table sur l'Ecran LCD

      SPLK  #0, LCDline  ; REW au début de la table

      SPLK  #0, LCDcol

;----------------------------------------------------------------

Communication diagram

We must send 3 bytes on the SPI in the following sequence.

DispLCD macro description

This macro sends 3 bytes on the SPI.
If the Order is 1 then it will send a configuration modification (clear screen, cursor home...).
If the Order is 2 then it will send a character corresponding to the Char Table (see below).

DispLCD .macro Order        ; 1=> ordre, 2 => Char, on utilise le LCDhi également pour les ordres ! 02/2007

      CS_LCDon

      LDP  #0E0h

      LACC  SPI_BUF

      .if Order=1   ; 1=> ordre, 2 => Char

      SPLK  #0F8h, SPI_DAT    ; Transmit start Ordre

      .endif

      .if Order=2   

      SPLK  #0FAh, SPI_DAT    ; Transmit start Order

      .endif

;   LACC SPI_BUF

lcd1? BIT  SPI_STATUS,BIT6

      BCND  lcd1?, NTC

      LACC  SPI_BUF

      LDP  #LCDlo

      LACC  LCDlo    

      LDP  #0E0h          

      SACL  SPI_DAT    ; Transmit Low byte

;   LACC SPI_BUF

lcd2? BIT  SPI_STATUS,BIT6

      BCND  lcd2?, NTC

      LACC  SPI_BUF

      LDP  #LCDhi

      LACC  LCDhi    

      LDP  #0E0h          

      SACL  SPI_DAT     ; Transmit hi byte

      LACC  SPI_BUF

lcd3? BIT  SPI_STATUS,BIT6

      BCND  lcd3?, NTC

      LACC  SPI_BUF

      CS_LCDoff

      .endm

According to the previous graph, the bits order is D0 to D7, but the SPI send the Hi bit first (MSB) (ie. from D7 to D0). So you have to implement a routine or macro, let's call it trChar (see below).

Char Table

trChar macro description

This macro inverts the byte to be sent. Form D0 through D7, it becomes D7 through D0.
Then it creates two bytes : LCDlo and LCDhi, that have only half of them that is non zero, according to the communication diagram.

;****************************************************************

; Routine trChar : transforme le char LCDChar en LCDChar_m (pour le LCD)

;****************************************************************

trChar .macro

        LDP  #LCDChar

        SPLK  #08h,tmp

        SPLK  #0000h,LCDChar_m

loop?  LACC LCDChar

        SFR  

        SACL  LCDChar

        LACC  LCDChar_m

        ROL

        SACL  LCDChar_m

        LACC  tmp

        SUB  #1

        SACL  tmp

        BNZ  loop?

        LACC  LCDChar_m

        AND  #00F0h

        SACL  LCDlo

        LACC  LCDChar_m,4

        AND  #00F0h

        SACL  LCDhi

        .endm

LCD instruction Table

This table is extracted from the full SAMSUNG KS0074 pdf driver file or from the SELTRONIC LCD pdf file : Instructions.pdf

Refresh the screen

An intersting use of this LCD screen is to display internal variables of the F240 program that is real time running.
According to an interrupt, let say every 100 us, we could write one character at a time.
So you can implement a table (2x16 characters) in memory where you write variables in Hex or Decimal (look at the page : Hex to Decimal conversion).

Every sampling period, you will check if you have to refresh the LCD screen and write 1 characters from the table to the LCD driver via the SPI interface.
Of course, for each character, you will invert its byte (D0 to D7), split it in 2 bytes of 4 bits significants data bits and zeroes the others bits, then sending the 3 bytes (header, LCDlo and LCDhi) on the SPI.

It works fine... and leave you enough time, within the 100 us sampling period, for sending on the SPI 2 bytes for TLV 5614 DAC refresh and for performing a V/f motor control... DSPs run incredibly fast :-)